***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr. 10, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5948V-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.308
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=99.7  VTO=3.79  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=1.439e12  gamma=1.05)
Rd     d1    d2    9.026e-3    TC=4.48e-3,5.95e-6
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=44  TBV1=5.807e-4 TBV2=3.05e-8  CJO=6.232e-10  M=1.182  VJ=9.625)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=2.259e-12  N=1.062  RS=4e-8  EG=1.14  TT=20n IKF=18.081 tikf=9.5e-3)
Rdiode  d1  21    9.255e-3 TC=3.5e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.795e-10
.MODEL     DGD    D(cjo=1.752e-10   M=1.384   VJ=5.823)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    5.445e-10
.ENDS PJQ5948V-AU
*$
